 | FATS - Fast Access Tree System | |||
| Inhaltsverzeichnis | |||
| Programmierschnittstellen | |||
| MS-Pascal für OS/2 | |||
| | ||||||||||||||||||||
Das nachfolgende Microsoft Pascal Beispiel demonstriert die Verwendung der von FATS bereitgestellten Index-Befehle:
 | "C" Create Indexfile (Indexdatei definieren, erstellen und öffnen.) |
| | "O" Open Indexfile (Indexdatei öffnen.) |
| | "K" Close Indexfile (Eine oder alle Indexdateien schließen.) |
| | "I" Insert Record ((Haupt)-Schlüssel in Indexdatei einfügen und Datensatznummer besetzen.) |
| | "F" Search First (Suchen des ersten Schlüssels.) |
| | "L" Search Last (Suchen des letzten Schlüssels.) |
| | "N" Search Next (Suchen des nächsten Schlüssels in Folge.) |
| | "A" Search Next After (Suchen des auf den angegebenen Schlüssel folgenden Schlüssels.) |
| | "E" Search Previous Before (Suchen des dem angegebenen Schlüssel vorangehenden Schlüssels.) |
| | "Y" Auto Refresh (Bestimmt das Verhalten der Bibliothek im Netzwerk- und Einzelplatzbetrieb.) |
(*
FATS 02.30
(c) GCS Software, Udo Gertz 1993-1998
Testprogramm (Microsoft Pascal, IBM Pascal)
Erstellen der Testdateien KUNDEN.DAT / KUNDEN.KEY
19-03-2009 U.Gertz
*)
program TST1_GER (input, output);
type
kundenrec = record
LOESCHKENNZ: char;
ANREDE: lstring(5);
NAME: lstring(25);
BRANCHE: lstring(25);
STRASSE: lstring(25);
PLZ: lstring(5);
ORT: lstring(20);
end;
const
fn_demo = '..\..\..\DEMODATA\KUNDEN.ASC';
fn_cust = 'KUNDEN.DAT';
var
hKunden: file of kundenrec;
hDemodata: text;
kpuffer: kundenrec;
szCmnd: lstring(255);
szFATSkey: lstring(255);
szRecno: lstring(8);
uFATSError: word;
count: word;
dwFATSRecno: integer4;
cChar: char;
(*
FATS Befehle ausführen
======================
Alle FATS Befehle werden mit einer Funktion ausgeführt:
*)
function FATSCALL (vars szCmnd: lstring; vars nErrorcode: word;
vars szReturnKey: lstring) : integer4; extern;
(*
Bedeutung der verwendeten Parameter:
szCmnd Dieser String definiert den auszuführenden FATS-
Befehl sowie die dazugehörenden Parameter.
nErrorcode Über diese Variable wird die Anwendung über
Erfolg (0) oder Mißerfolg (<> 0) der letzten
FATS-Aktion unterrichtet.
szReturnKey Ein gefundener Schlüssel wird in diesem String
gespeichert.
Rückgabewert: Datensatznummer
*)
begin
writeln;
writeln ('Um Ihre Programme zu übersetzen ist eine der folgenden Methoden zu wählen: ');
writeln;
writeln (' 1. Methode: FATS an das Anwendungsprogramm binden ');
writeln;
writeln (' PAS1 TST1_GER');
writeln (' PAS2');
writeln (' LINK TST1_GER FATS.OBJ FATS_MSP.OBJ');
writeln;
writeln (' 2. Methode: Aufruf der Dynamischen Bibliothek (DLL)');
writeln;
writeln (' PAS1 TST1_GER');
writeln (' PAS2');
writeln (' LINK TST1_GER FATSMSPD.OBJ FATS_O16.LIB');
writeln;
writeln (' oder wenn Sie die erweiterte Version von FATS besitzen:');
writeln;
writeln (' LINK TST1_GER FATSMSPD.OBJ FATSXO16.LIB');
writeln;
writeln ('Bitte [ENTER] drücken...');
writeln;
read(cChar);
(*
-------> Aktivierung des Netzwerkbetriebes
"Y" Auto Refresh Kommando
FATS ist standardmäßig für den Betrieb im Netzwerk ausgestattet.
Beinahe alle Befehle können sowohl im Einzelplatz- als auch im
Netzwerkbetrieb ausgeführt werden.
Standardmäßig sind die Netzfunktionen ausgeschaltet. Sie können
diese mit dem Befehl "Y\2" initialisieren.
Diese Initialisierung wird normalerweise beim Programmstart
erledigt und gilt dann für die gesamte Laufzeit des Programmes.
*) 
szCmnd:='Y\2';
dwFATSRecno:=FATSCALL(szCmnd, uFATSError, szFATSkey);
(*
-------> ASCII-Datei mit Demodaten öffnen
*)
assign (hDemodata, fn_demo);
reset (hDemodata);
(*
-------> Datendatei erstellen
*)
writeln ('Datendatei wird erstellt ...');
assign (hKunden, fn_cust);
hKunden.mode:=direct;
rewrite (hKunden);
(*
-------> Indexdatei erstellen
*)
(*
"C" Create Indexfile
Mit diesem Befehl erstellen Sie eine Indexdatei, wobei eine
eventuell bereits vorhandene Datei mit demselben Dateinamen
gelöscht wird.
Die Indexdatei wird dabei gleichzeitig mit den über den
Befehl Auto Refresh (Y) definierten Öffnungsflags geöffnet
und der Dateinummer "FileNo" zugewiesen. Diese Nummer muß bei
allen nachfolgenden FATS-Befehlen angegeben werden, um mit
der Indexdatei zu arbeiten.
Maximal 200 Schlüssel pro Datensatz können in einer Indexdatei
verwaltet werden, wobei die maximale Schlüssellänge 240 Zeichen
beträgt.
Beachten Sie bei der Dateipfadangabe, daß der Backslash (\) von
FATS als Trennzeichen behandelt wird und daher im Pfad durch
einen normalen Schrägstrich ersetzt werden sollte.
Alternativ dazu können Sie auch das Trennzeichen umdefinieren,
indem Sie dieses als erstes Zeichen im Befehlsstring angeben,
z.B. szCmnd = "&C&C:\ARTIKEL.KEY&1&1&A&1" (das Trennzeichen muß
ein ASCII-Zeichen kleiner als 48 sein).
Der Aufbau des Kommandostrings:
szCmnd = "C\{Filename}\{KeyLength}\{KeyCount}\{KeyType}\{FileNo}"
FileName Name der Datei, eventuell mit Pfadangabe
(z.B. C:/DATEN/ARTIKEL.KEY oder ARTIKEL.KEY)
KeyLength Maximale Länge der Schlüssel
KeyCount Anzahl Schlüssel (1-200)
KeyType Art der Schlüssel (A=ASCII Textschlüssel, I=Integer)
FileNo Nummer der Indexdatei (1-40)
*)
writeln ('Indexdatei wird erstellt ...');
szCmnd:='C\KUNDEN.KEY\25\3\A\1';
dwFATSRecno:=FATSCALL(szCmnd, uFATSError, szFATSkey);
(*
========================================================================
Datensätze einfügen
========================================================================
*)
writeln;
writeln ('Es werden jetzt 222 Datensätze in die Datei eingefügt. Für jeden');
writeln ('Datensatz werden 3 Schlüssel in die Indexdatei eingefügt.');
writeln;
writeln ('Bitte [ENTER] drücken...');
read(cChar);
count:=0;
repeat
kpuffer.LOESCHKENNZ:=' ';
read(hDemodata, kpuffer.ANREDE);
read(hDemodata, kpuffer.NAME);
read(hDemodata, kpuffer.BRANCHE);
read(hDemodata, kpuffer.STRASSE);
read(hDemodata, kpuffer.PLZ);
read(hDemodata, kpuffer.ORT);
(*
"I" Insert Record
Diesem Befehl wird die im "Create Indexfile"-Befehl
angegebene Anzahl Schlüssel im Kommandostring übergeben.
Die Schlüssel werden in die Indexdatei einsortiert und
einer Satznummer zugeordnet, welche in der "RECNO"
Variable an das Anwenderprogramm zurückgegeben wird.
Anschließend sollte das aufrufende Programm den zugehörigen
Datensatz entsprechend der zurückgegebenen Satznummer in
die Datendatei speichern.
Die Länge der übergebenen Schlüssel darf die beim
"Create-Indexfile" angegebene Länge nicht überschreiten,
kürzere Schlüssel werden mit dem ASCII-Zeichen 00h auf die
maximale Schlüssellänge erweitert.
Der Aufbau des Kommandostrings:
szCmnd = "I\{FileNo}\{KeyStr1}[\{KeyStr2}[\{KeyStr3}]]"
FileNo Nummer der Indexdatei
KeyStr# Schlüssel
*)
szCmnd:='I\1\';
concat(szCmnd, kpuffer.NAME);
concat(szCmnd, '\');
concat(szCmnd, kpuffer.BRANCHE);
concat(szCmnd, '\');
concat(szCmnd, kpuffer.PLZ);
concat(szCmnd, kpuffer.ORT);
dwFATSRecno:=FATSCALL(szCmnd, uFATSError, szFATSkey);
If (uFATSError = 0) Then Begin
seek(hKunden, dwFATSRecno);
hKunden^:=kpuffer;
put(hKunden);
writeln(kpuffer.NAME,' --> Satznummer ', dwFATSRecno:-8);
End;
count:=count+1;
until (count = 222) or (uFATSError <> 0);
close(hDemodata);
(*
"K" Close Indexfile
Mit diesem Befehl schließen Sie die über "FileNo"
angegebene Indexdatei.
Wenn Sie den Datencache mit dem Befehl Auto Refresh (Y)
aktiviert haben, dann werden eventuell noch im Cachepuffer
befindliche Daten automatisch auf die Platte geschrieben,
was Sie jedoch auch jederzeit mit dem Befehl Write Page
Map (W) erzwingen können.
Wenn der Datencache inaktiv ist, dann werden nach jedem
FATS-Befehl sämtliche veränderten Daten auf die Platte
geschrieben. Das Schließen der Dateien ist daher nur vor dem
Beenden des aufrufenden Programmes notwendig.
Wenn Sie den Parameter "FileNo" weglassen, dann werden alle
geöffneten Indexdateien geschlossen. Diese Variante empfiehlt
sich vor der Beendigung des Anwendungsprogrammes.
Der Aufbau des Kommandostrings:
szCmnd = "K\{FileNo}"
FileNo Nummer der Indexdatei
*)
szCmnd:='K\1';
dwFATSRecno:=FATSCALL(szCmnd, uFATSError, szFATSkey);
(*
========================================================================
Suche im Index
========================================================================
*)
(*
"O" Open Indexfile
Mit diesem Befehl wird die über "FileName" bestimmte
Indexdatei mit den über den Befehl Auto Refresh (Y)
definierten Öffnungsflags geöffnet und der Dateinummer
"FileNo" zugewiesen. Diese Nummer muß bei allen nach-
folgenden FATS-Befehlen angegeben werden, um mit der
Indexdatei zu arbeiten.
Eine eventuell mit der gleichen Dateinummer bereits
geöffnete Indexdatei wird zuvor geschlossen.
Beachten Sie bei der Dateipfadangabe, daß der Backslash
(\) von FATS als Trennzeichen behandelt wird und daher
im Pfad durch einen normalen Schrägstrich ersetzt werden
sollte.
Alternativ dazu können Sie auch das Trennzeichen
umdefinieren, indem Sie dieses als erstes Zeichen im
Befehlsstring angeben, z.B. szCmnd = "&O&C:\ARTIKEL.KEY&1"
(das Trennzeichen muß ein ASCII-Zeichen kleiner als 48 sein).
Der Aufbau des Kommandostrings:
szCmnd = "O\{FileName}\{FileNo}"
FileName Name der Datei, eventuell mit Pfadangabe
(z.B. C:/DATEN/ARTIKEL.KEY oder ARTIKEL.KEY)
FileNo Nummer der Indexdatei
*)
szCmnd:='O\KUNDEN.KEY\1';
dwFATSRecno:=FATSCALL(szCmnd, uFATSError, szFATSkey);
(*
-------> Datensätze nach Name sortiert ausgeben
*)
writeln;
writeln ('Die Datensätze werden jetzt anhand des ersten Schlüssels (NAME)');
writeln ('aufsteigend sortiert ausgegeben. Der dabei verwendete FATS-Befehl');
writeln ('SEARCH NEXT AFTER kann im Einzelplatz und im Netzwerk verwendet');
writeln ('werden.');
writeln;
writeln ('Bitte [ENTER] drücken...');
read(cChar);
(*
"F" Search First
Dieser Befehl gibt die Datensatznummer und den Schlüsselwert
des kleinsten Schlüssels der angegebenen Schlüsselnummer
zurück.
Der Aufbau des Kommandostrings:
szCmnd = "F\{KeyNo}\{FileNo}"
KeyNo Schlüsselnummer
FileNo Nummer der Indexdatei
*)
szCmnd:='F\1\1';
repeat
dwFATSRecno:=FATSCALL(szCmnd, uFATSError, szFATSkey);
if (uFATSError = 0) and (encode(szRecno, dwFATSRecno:8)) then begin
seek(hKunden, dwFATSRecno);
get(hKunden);
kpuffer:=hKunden^;
writeln(kpuffer.NAME, ' --> Satznummer ', dwFATSRecno:-8);
(*
"A" Search Next After
Dieser Befehl sucht den über "KeyString" und "RecNo"
spezifizierten Schlüssel in der Indexdatei und blättert dann
um eine Position weiter.
Als Ergebnis wird der auf den angegebenen Schlüssel folgende
Schlüssel zurückgegeben. Der Aufruf entspricht daher den
Befehlen Search Generic (G) mit anschließendem Search Next (N).
Im Gegensatz zum Befehl "Search Next" kann dieser Befehl auch
problemlos im Netzwerk verwendet werden.
Der Aufbau des Kommandostrings:
szCmnd = "A\{KeyNo}\{RecNo}\{FileNo}\{KeyString}"
KeyNo Schlüsselnummer
RecNo Datensatznummer
FileNo Nummer der Indexdatei
KeyString Schlüssel
*)
szCmnd:='A\1\';
concat(szCmnd, szRecno);
concat(szCmnd, '\1\');
concat(szCmnd, szFATSkey);
end;
until uFATSError <> 0;
(*
--------> Datensätze nach Branche sortiert ausgeben
*)
writeln;
writeln ('Die Datensätze werden jetzt anhand des zweiten Schlüssels (BRANCHE)');
writeln ('aufsteigend sortiert ausgegeben.');
writeln;
writeln ('Bitte [ENTER] drücken...');
read(cChar);
szCmnd:='F\2\1';
repeat
dwFATSRecno:=FATSCALL(szCmnd, uFATSError, szFATSkey);
if uFATSError = 0 then begin
seek(hKunden, dwFATSRecno);
get(hKunden);
kpuffer:=hKunden^;
writeln(kpuffer.BRANCHE, ' ', kpuffer.NAME, ' --> Satznummer ', dwFATSRecno:-8);
(*
"N" Search Next
Dieser Befehl gibt die Datensatznummer und den
Schlüsselwert des nächsten Schlüssels zurück.
Ausgegangen wird dabei vom Ergebnis des letzten
Suchbefehls, d.h. unmittelbar vor der Anwendung
dieses Befehls muß ein beliebiger Such-Befehl,
ausgeführt worden sein.
Jede Veränderung der Indexdatei durch das Einfügen
oder Löschen von Schlüsseln macht einen für diesen
Befehl notwendigen internen Zeiger ungültig, wodurch
der Next-Befehl fehlschlägt. Da dies im Netzwerk auch
von einer anderen Station aus passieren kann, sollte
in Netzwerkumgebungen der Befehl Search Next After (A)
verwendet werden.
Wenn es keinen nächsten Schlüssel gibt, d.h. der zuletzt
gefundene Schlüssel der Letzte in Folge war, wird der
Fehlercode #15 zurückgegeben.
Der Aufbau des Kommandostrings:
szCmnd = "N\{FileNo}"
FileNo Nummer der Indexdatei
*)
szCmnd:='N\1';
end;
until uFATSError <> 0;
(*
--------> Datensätze nach PLZ & Ort sortiert ausgeben
*)
writeln;
writeln ('Die Datensätze werden jetzt anhand des dritten Schlüssels (PLZ/ORT)');
writeln ('absteigend sortiert ausgegeben.');
writeln;
writeln ('Bitte [ENTER] drücken...');
read(cChar);
(*
"L" Search Last
Dieser Befehl gibt die Datensatznummer und den Schlüsselwert
des größten Schlüssels der angegebenen Schlüsselnummer zurück.
Der Aufbau des Kommandostrings:
szCmnd = "L\{KeyNo}\{FileNo}"
KeyNo Schlüsselnummer
FileNo Nummer der Indexdatei
*)
szCmnd:='L\3\1';
repeat
dwFATSRecno:=FATSCALL(szCmnd, uFATSError, szFATSkey);
if (uFATSError = 0) and (encode(szRecno, dwFATSRecno:8)) then begin
seek(hKunden, dwFATSRecno);
get(hKunden);
kpuffer:=hKunden^;
writeln(kpuffer.PLZ,' ', kpuffer.ORT, ' ', kpuffer.NAME, ' --> Satznummer ', dwFATSRecno:-8);
(*
"E" Search Previous Before
Dieser Befehl sucht den über "KeyString" und "RecNo"
spezifizierten Schlüssel in der Indexdatei und blättert dann
um eine Position zurück.
Als Ergebnis wird der dem angegebenen Schlüssel vorangehende
Schlüssel zurückgegeben. Der Aufruf entspricht daher den
Befehlen "Search Generic" mit anschließendem "Search Prev".
Im Gegensatz zum Befehl "Search Previous" kann dieser Befehl
auch problemlos im Netzwerk verwendet werden.
Der Aufbau des Kommandostrings:
szCmnd = "E\{KeyNo}\{RecNo}\{FileNo}\{KeyString}"
KeyNo Schlüsselnummer
RecNo Datensatznummer
FileNo Nummer der Indexdatei
KeyString Schlüssel
*)
szCmnd:='E\3\';
concat(szCmnd, szRecno);
concat(szCmnd, '\1\');
concat(szCmnd, szFATSkey);
end;
until uFATSError <> 0;
(*
--------> Indexdatei schließen
*)
szCmnd:='K\1';
dwFATSRecno:=FATSCALL(szCmnd, uFATSError, szFATSkey);
close(hKunden);
end.
© 2008 
GCS Software, Udo Gertz